Sergey Kovalyov

Adobe focuses on technologies which actually work

2011-11-09T12:58:00.000+02:00

According to rumors, which are likely to be confirmed soon, Adobe has stopped development on Flash Player for browsers on mobile.

Easy to guess that it will trigger an avalanche of sarcastic comments from fanboys who have no clue about the technology.

This already happens.

But is it really game changing announcement?

Definitely not!

In fact, nothing has changed, because until now there was no single significant Flash project targeting mobile browsers.

From the very beginning with Flash Lite the whole idea of delivering ANY SWF to mobile browser was weak.

Complex web applications are not suitable for that at all from UI and performance perspective.

Games could be and should be packaged as apps and some companies already do so.

Ads with the flying tagline and pulsating product picture? Well, I do not really care about ads, but this is probably the area where so called HTML5 is already good enough.

That is why I totally support Adobe's move to sharpen focus on:

Desktop Flash Player. It is crucial to choose the right tool for the right task. Using Flash for simple wizard nowdays is nonsense. At the same time it remains the obvious choice for complex web applications. With Flash Builder and Flex SDK you can build high-quality applications with unbeatable performance which work the same in all browsers on all operation systems. Other than that there are still a lot of important features which are either not supported as such or virtually impossible to implement and maintain with HTML/CSS/JS stack of technologies. When you attach multiple files in GMail - it's Flash. Charts in Google Analytics Flash again. All more or less complex operations with media content from Grooveshark to YouTube are also implemented in Flash.

Air as a tool to build cross platform apps. Now also for mobile. Although there is huge iOS domination in smartphone and tablet markets, there are some other platforms already present on the market and it is quite possible that new will appear. Companies have to invest a lot to address all of them with native apps. For giants it is not a big issue. For certain performance sensitive applications it will remain inevitable as well. But with latest releases from Adobe and native extensions support Air becomes the best choice for many others. With single code base you address iOS, Android and other platforms and use any platform specific feature when needed.

HTML5 authoring software. There is too much hype about HTML5 (mostly from people who know this buzzword only from Steve Jobs famous Thoughts on Flash), but until now there are no tools for creative professionals to produce content comparable even to Flash 3 (more than 10 years ago!). Every single HTML5 ad, demo, promo is PROGRAMMED by frontend developers. For sure this must be changed. And there is a big opportunity for Adobe here. Hopefully in future JavaScript, that is probably the worst programming language in the world, will evolve to something like ActionScript 3.0 and we will see HTML5 authoring software not only for designers and animators, but also for developers.

UPDATE

http://www.beautifycode.com/flash-mobile-died-so-what
http://gskinner.com/blog/archives/2011/11/flash-player-mobile-a-post-mortem.html
http://www.leebrimelow.com/?p=3151

How to format the time span between now and the date specified in a "Facebook way"

2010-09-22T19:19:00.008+03:00

Recently I was looking for some method to format the time span between now and the date specified in a "Facebook way". There are some, but none was completely what I was looking for. So I have decided to create mine. Moreover, it's not that complicated:

package {

    import mx.formatters.DateFormatter;
    import mx.utils.StringUtil;

    public class DateUtil {
        
        public static const SECOND_IN_MILLISECONDS : int = 1000;
        
        public static const FEW_SECONDS : int = 5;

        public static const MINUTE_IN_SECONDS : int = 60;
        
        public static const HOUR_IN_SECONDS : int = MINUTE_IN_SECONDS * 60;
        
        private static const X_SECONDS_AGO : String = "{0} seconds ago";
        
        private static const X_MINUTES_AGO : String = "{0} minutes ago";
        
        private static const X_HOURS_AGO : String = "{0} hours ago";
        
        private static const IN_X_SECONDS : String = "In {0} seconds";

        private static const IN_X_MINUTES : String = "In {0} minutes";

        private static const IN_X_HOURS : String = "In {0} hours";
        
        private static const YESTERDAY_TOMORROW_PATTERN : String = "at L:NNA";
        
        private static const THIS_WEEK_PATTERN : String = "EEEE at L:NNA";
        
        private static const THIS_YEAR_PATTERN : String = "MMMM D at L:NNA";
        
        private static const ANOTHER_YEAR_PATTERN : String = "MMMM D, YYYY at L:NNA";

        /**
         * Format the time span between now and the date specified in a "Facebook way".
         *
         * Examples:
         *
         * May 18, 2011 at 5:11AM
         * December 25 at 8:43PM
         * Friday at 3:53PM
         * Tomorrow at 10:44AM
         * In 10 hours
         * In about an hour
         * In 25 minutes
         * In about a minute
         * In 17 seconds
         * In a few seconds
         * A few seconds ago
         * 31 seconds ago
         * About a minute ago
         * 47 minutes ago
         * About an hour ago
         * 4 hours ago
         * Yesterday at 6:25PM
         * Monday at 12:30AM
         * September 11 at 7:11AM
         * September 10, 2009 at 12:23PM
         */
        public static function getTimeSpan(date : Date) : String {
            var result : String;
            var now : Date = new Date();
            var dateFormatter : DateFormatter = new DateFormatter();
            var range : Number = (now.time - date.time) / SECOND_IN_MILLISECONDS;

            var nextYearStart : Date = new Date(now.fullYear + 1, 0, 1);
            var nextWeekStart : Date = new Date(now.fullYear, now.month, now.date + (7 - now.day));
            var tomorrowStart : Date = new Date(now.fullYear, now.month, now.date + 1);
            var theDayAfterTomorrowStart : Date = new Date(now.fullYear, now.month, now.date + 2);
            var todayStart : Date = new Date(now.fullYear, now.month, now.date);
            var yesterdayStart : Date = new Date(now.fullYear, now.month, now.date - 1);
            var thisWeekStart : Date = new Date(now.fullYear, now.month, now.date - now.day);
            var thisYearStart : Date = new Date(now.fullYear, 0, 1);
            
            var nextYearRange : Number = (now.time - nextYearStart.time) / SECOND_IN_MILLISECONDS;
            var nextWeekRange : Number = (now.time - nextWeekStart.time) / SECOND_IN_MILLISECONDS;
            var theDayAfterTomorrowRange : Number = (now.time - theDayAfterTomorrowStart.time) / SECOND_IN_MILLISECONDS;
            var tomorrowRange : Number = (now.time - tomorrowStart.time) / SECOND_IN_MILLISECONDS;
            var todayRange : Number = (now.time - todayStart.time) / SECOND_IN_MILLISECONDS;
            var yesterdayRange : Number = (now.time - yesterdayStart.time) / SECOND_IN_MILLISECONDS;
            var thisWeekRange : Number = (now.time - thisWeekStart.time) / SECOND_IN_MILLISECONDS;
            var thisYearRange : Number = (now.time - thisYearStart.time) / SECOND_IN_MILLISECONDS;

            if (range >= 0) {
                if (range < FEW_SECONDS) {
                    result = "A few seconds ago";
                } else if (range < MINUTE_IN_SECONDS) {
                    result = StringUtil.substitute(X_SECONDS_AGO, Math.floor(range));
                } else if (range < MINUTE_IN_SECONDS * 2) {
                    result = "About a minute ago";
                } else if (range < HOUR_IN_SECONDS) {
                    result = StringUtil.substitute(X_MINUTES_AGO, Math.floor(range / MINUTE_IN_SECONDS));
                } else if (range < HOUR_IN_SECONDS * 2) {
                    result = "About an hour ago";
                } else if (range < todayRange) {
                    result = StringUtil.substitute(X_HOURS_AGO, Math.floor(range / HOUR_IN_SECONDS));
                } else if (range < yesterdayRange) {
                    dateFormatter.formatString = YESTERDAY_TOMORROW_PATTERN;
                    result = "Yesterday " + dateFormatter.format(date);
                } else if (range < thisWeekRange) {
                    dateFormatter.formatString = THIS_WEEK_PATTERN;
                    result = dateFormatter.format(date);
                } else if (range < thisYearRange) {
                    dateFormatter.formatString = THIS_YEAR_PATTERN;
                    result = dateFormatter.format(date);
                } else {
                    dateFormatter.formatString = ANOTHER_YEAR_PATTERN;
                    result = dateFormatter.format(date);
                }
            } else {
                if (range > -FEW_SECONDS) {
                    result = "In a few seconds";
                } else if (range > -MINUTE_IN_SECONDS) {
                    result = StringUtil.substitute(IN_X_SECONDS, Math.floor(-range));
                } else if (range > -MINUTE_IN_SECONDS * 2) {
                    result = "In about a minute";
                } else if (range > -HOUR_IN_SECONDS) {
                    result = StringUtil.substitute(IN_X_MINUTES, Math.floor(-range / MINUTE_IN_SECONDS));
                } else if (range > -HOUR_IN_SECONDS * 2) {
                    result = "In about an hour";
                } else if (range > tomorrowRange) {
                    result = StringUtil.substitute(IN_X_HOURS, Math.floor(-range / HOUR_IN_SECONDS));
                } else if (range > theDayAfterTomorrowRange) {
                    dateFormatter.formatString = YESTERDAY_TOMORROW_PATTERN;
                    result = "Tomorrow " + dateFormatter.format(date);
                } else if (range > nextWeekRange) {
                    dateFormatter.formatString = THIS_WEEK_PATTERN;
                    result = dateFormatter.format(date);
                } else if (range > nextYearRange) {
                    dateFormatter.formatString = THIS_YEAR_PATTERN;
                    result = dateFormatter.format(date);
                } else {
                    dateFormatter.formatString = ANOTHER_YEAR_PATTERN;
                    result = dateFormatter.format(date);
                }
            }
            
            return result;
        }
    }
}

Do not comment code!

2008-11-06T15:51:00.002+02:00

Commenting code is the worst practice promoted by "wannabe smart" books about software engineering. Joshua Block in his How to Design a Good API and Why it Matters keynote notes that code should read like prose and shows the good example:

if (car.speed() > 2 * SPEED_LIMIT)
    generateAlert("Watch out for cops!");

And I completely agree with this statement. Thus good code is self-explanatory and does not require comments. On the other hand comments will never rescue bad code. Sure, we can use something like "TODO: I will fix this dummy trick in the next iteration", but no more than it.

Second Ukrainian Flash Platform User Group official meeting

2008-05-12T12:09:00.002+03:00

This time Ukrainian Flash Platform User Group meeting has been held in Kiev. Two previous meetings have been held in Kharkov. We have gathered at cozy Golden Gate Pub of Mirovaya Karta chain near Golden Gates. Ilya Panin from Kharkov has compared different IDEs (Adobe Flex Builder, FDT, FlashDevelop, IDEA) and summarized that as a whole Adobe Flex Builder is the best choice to develop Flex applications now. Tatyana Belaya from Moscow has told about sound visualization using SoundMixer.computeSpectrum() method with snowflakes on background. Roman Shuper has shared his experience using Apache Ant to deploy Flex projects and also told about conditional compilation and running executables from AIR applications.

Flex SDK coding conventions and best practices

2008-04-17T09:19:00.002+02:00

Adobe has published Flex SDK coding conventions and best practices. Now it is mostly about ActionScript 3.0. I work in a team for a long time, so we have created our own conventions long time ago, because it is a must for collaborative development. It is based on ActionScript 2.0 Best Practices, Code Conventions for the Java Programming Language and the common sense. Nevertheless, it's a great effort from Adobe, because vendor supported guidelines are always more respected and tend to become industry standard. Now I hope Adobe would also extend the document with MXML conventions.

First Ukrainian Flash Platform User Group official meeting

2008-03-17T14:43:00.002+02:00

The meeting has been hosted by Kharkov office of GlobalLogic, formerly known as Validio. Eldar Prilutsky has introduced ActionScript 3.0 event model, Rostislav Siryk has shared his experience with PureMVC framework while developing Moscow vector map and Denis Papazov has told about Flash Media Server.

Macromedia Flash 2 box!

2008-03-11T23:44:00.001+02:00

States and form layout

2007-10-08T14:22:00.000+02:00

I have created component based on Form container and it has some states with AddChild overrides. Unfortunately, adding new FormItem to the Form instance runtime doesn't force the Form instance to update its layout. Thus labels are not aligned correctly as it's expected. Actually, it's known bug and Adobe plans to fix it in SDK Moxie RC. Yet they recommend to use workaround and call invalidateSize() on Form instance's children upon state change. I have implemented it in ExtendedForm, that could be reused easily the same way you use native Form:

package {

    import mx.containers.Form;
    import mx.core.UIComponent;
    import mx.events.FlexEvent;

    public class ExtendedForm extends Form {

        public function ExtendedForm() {
            super();
            
            addEventListener(FlexEvent.UPDATE_COMPLETE, onUpdateComplete);
        }
        
        private function onUpdateComplete(event : FlexEvent) : void {
            for (var i : int = 0; i < numChildren; i++) {
                UIComponent(getChildAt(i)).invalidateSize();
            }
        }
        
    }

}

A brand new site about Russia

2007-07-04T10:47:00.000+03:00

Wow, Russia is the biggest country in the wolrd. Aloha!

Yes, guys, it is. So everybody knows that there are two cities in Russia - Moscow and St. Petersburg. That is also true. The rest of the country is called Siberia. That's it. Pretty simple geography.

So what else do we have in Russia? We have bears, of course. A lots of different bears. Some of them are wearing lapti and playing balalayka all day long, some of them are drinking vodka all the time, some of them can fly, some live in the internet, some went to politics and some are just hanging out in the streets.

Great Flash site about Kalashnikov, Ushanka, Matrioshka and... Chelsea. :)

The World Leader in Evaporative Cooling?

2007-06-12T19:04:00.000+03:00

It was found that Adobe AIR is The World Leader in Evaporative Cooling. :)

Constraint-based layout vs. nested layout containers

2007-04-24T13:39:00.000+02:00

I have heard different opinions regarding what layout technique is better, though I would strongly recommend nested layout containers wherever it's possible. Sure, if you want your components to overlap each other, using Canvas is the only option, but don't use it when nested layout containers fit better:

<mx:Canvas width="100%" height="50%">
    <mx:TextInput id="myTextInput" x="10" y="10" />
    <mx:TextArea id="myTextArea" x="10" y="{myTextInput.y + myTextInput.height + 10}" />
    <mx:NumericStepper id="myNumericStepper" x="10" y="{myTextArea.y + myTextArea.height + 10}" />
</mx:Canvas>

vs.

<mx:VBox width="100%" height="50%" paddingLeft="10" paddingTop="10" verticalGap="10">
    <mx:TextInput />
    <mx:TextArea />
    <mx:NumericStepper />
</mx:VBox>

The same result, but even in this very simple example the second option is much more laconic.

Text control with truncateToFit property support

2007-02-17T23:46:00.000+02:00

As you probably know, Label control supports truncateToFit property, while Text doesn't. Even if you explicitly set it to true in your particular Text instance, nothing happens. I have created TruncatedText class that acts the similar way as Label does. If a TruncatedText instance is sized to be smaller than its text, the text is truncated with "...":

package {

    import mx.controls.Text;
    import mx.core.UITextField;
    import mx.core.mx_internal;

    use namespace mx_internal;

    public class TruncatedText extends Text {
        
        protected static const TRUNCATION_INDICATOR : String = "...";

        public function TruncatedText() {
            super();
            
            truncateToFit = true;
        }
        
        override public function set text(text : String) : void {
            _isHTML = false;

            super.text = text;
        }
        
        override public function set htmlText(htmlText : String) : void {
            _isHTML = true;

             super.htmlText = htmlText;
        }
        
        protected function get truncationRequired() : Boolean {
            return (textField.height < textField.textHeight + UITextField.TEXT_HEIGHT_PADDING);
        }
        
        override protected function updateDisplayList(w : Number, h : Number) : void {
            super.updateDisplayList(w, h);
            
            if (truncateToFit) {
                if (!_isHTML) {
                    var originalText : String = textField.text = super.text;
                    if (truncationRequired) {
                        var l : int = 0;
                        var r : int = textField.text.length;
                        while (r - l > 1) {
                            var median : Number = Math.floor((l + r) / 2);
                            textField.text = originalText.substr(0, median) + TRUNCATION_INDICATOR;
                            if (truncationRequired) {
                                r = median;
                            } else {
                                l = median;
                            }
                        }
                        while (truncationRequired && median > 0) {
                            median--;
                            textField.text = originalText.substr(0, median) + TRUNCATION_INDICATOR;
                        }
                    }
                }
            }
            
        }
        
        private var _isHTML : Boolean;
        
    }

}

How to prevent pop-up blocking in Firefox

2007-01-10T12:01:00.001+02:00

Using navigateToURL() method causes pop-up blocking feature activation in Firefox since Flash is a plug-in:

navigateToURL(new URLRequest("http://http://skovalyov.blogspot.com/"), "_blank");

Use window.open() JavaScript method instead. I have created URLUtil class with openWindow() static method to make it easier:

package {

    import flash.external.ExternalInterface;

    public class URLUtil    {

        protected static const WINDOW_OPEN_FUNCTION : String = "window.open";

        public static function openWindow(url : String, window : String = "_blank", features : String = "") : void {
            ExternalInterface.call(WINDOW_OPEN_FUNCTION, url, window, features);
        }

    }

}

Now my blog could be opened in a new browser window this way:

URLUtil.openWindow("http://skovalyov.blogspot.com/");

Left aligned label in FormItem

2007-01-09T13:51:00.000+02:00

FormItem class doesn't have any styles or properties to control corresponding label alignment. Right alignment is applied by default and it's good idea to keep it "as is", because some usability researches say it's more friendly for user. Though if you want to make your FormItem label left aligned, use ExtendedFormItem class instead of regular FormItem:

package {
    
    import flash.display.DisplayObject;
    
    import mx.containers.FormItem;
    import mx.controls.Label;
    import mx.styles.CSSStyleDeclaration;
    import mx.styles.StyleManager;

    [Style(name="labelAlign", type="String", enumeration="left,right", inherit="no")]

    public class ExtendedFormItem extends FormItem {
        
        private static const CLASS_NAME : String = "ExtendedFormItem";
        
        private static var classConstructed : Boolean = staticConstructor();

        private static function staticConstructor() : Boolean {
            if (!StyleManager.getStyleDeclaration(CLASS_NAME)) {
                var newStyleDeclaration : CSSStyleDeclaration = new CSSStyleDeclaration();
                newStyleDeclaration.setStyle("labelAlign", "left");
                StyleManager.setStyleDeclaration(CLASS_NAME, newStyleDeclaration, true);
            }
            return true;
        }
        
        override public function styleChanged(styleProp : String) : void {
            super.styleChanged(styleProp);
            switch (styleProp) {
                case "labelAlign" :
                    invalidateDisplayList();
                    break;
            }
        }

        override protected function updateDisplayList(w : Number, h : Number) : void {
            super.updateDisplayList(w, h);
            if (label.length > 0) {
                var labelAlign : String = getStyle("labelAlign");
                var labelIndex : int = (required ? rawChildren.numChildren - 2 : rawChildren.numChildren - 1);
                var label : Label = Label(rawChildren.getChildAt(labelIndex));
                if (labelAlign == "left") {
                    label.x = 0;
                    if (required) {
                        var indicator : DisplayObject = rawChildren.getChildAt(rawChildren.numChildren - 1);
                        indicator.x = label.width + ((getStyle("indicatorGap") - indicator.width) / 2);
                    }
                }
            }
        }
        
    }

}

ExtendedFormItem label is left aligned by default, but you can set labelAlign style to "right" if necessary.

Invalidation mechanism for non-UI classes

2007-01-02T16:48:00.000+02:00

Invalidation mechanism is very useful to synchronize modifications to components. Though it's "built-in" in UIComponent and its successors, sometimes you need it in non-UI classes. I have created InvalidatingEventDispatcher abstract class inherited from EventDispatcher for this purpose. Just call invalidateProperties() whenever you want to mark your class instance so that its commitProperties() method gets called during the next timer tick (1 sec / frame rate). Override commitProperties() in your particular subclass implementation as well. Use validateNow() method to force validation.

package {

    import flash.events.EventDispatcher;
    import flash.events.IEventDispatcher;
    import flash.events.TimerEvent;
    import flash.utils.Timer;

    public class InvalidatingEventDispatcher extends EventDispatcher {
        
        protected var timer : Timer;

        public function InvalidatingEventDispatcher(target : IEventDispatcher = null) {
            super(target);
            
            timer = new Timer(1, 1);
            timer.addEventListener(TimerEvent.TIMER_COMPLETE, onTimerComplete);
        }
        
        public function validateNow() : void {
            validateProperties();
        }
        
        public function validateProperties() : void {
            if (timer.running) {
                commitProperties();
                timer.stop();
            }
        }
        
        public function invalidateProperties() : void {
            if (!timer.running) {
                timer.start();
            }
        }
        
        protected function commitProperties() : void {
        }
        
        private function onTimerComplete(event : TimerEvent) : void {
            commitProperties();
        }        
        
    }

}

Singleton in ActionScript 3.0

2006-12-28T18:38:00.000+02:00

There are some ways to create singleton in ActionScript 3.0, though I prefer public "facade" with static initialization of internal class:

package {

    public class AuthenticationManager {
        
        public static var instance : AuthenticationManagerInstance = new AuthenticationManagerInstance();
        
    }
    
}

Internal class (it should be in the same package with "facade"):

package {
    
    internal class AuthenticationManagerInstance extends EventDispatcher {
        
        public function AuthenticationManagerInstance() {
            super();
        }
        
        public function authenticate(username : String, password : String) : void {
            // Authentication routine
        }
                
    }
}

Usage example:

AuthenticationManager.instance.authenticate(usernameTextInput.text, passwordTextInput.text);

Make the focused child visible!

2006-12-27T19:30:00.000+02:00

Probably, one of the most annoying thing about Flex is lack of "browser native" features support. For example, if you have scrollable container it doesn't scroll its content upon Tab button click to make the focused child visible. However, browser do this! I have created easy to use class AutoScrollManager that makes it possible in Flex:

package {
    
    import flash.display.InteractiveObject;
    import flash.events.EventDispatcher;
    import flash.events.FocusEvent;
    import flash.events.TimerEvent;
    import flash.geom.Point;
    import flash.utils.Timer;
    
    import mx.collections.ArrayCollection;
    import mx.core.Application;
    import mx.core.Container;
    import mx.core.EdgeMetrics;
    import mx.core.IFlexDisplayObject;
    import mx.core.IMXMLObject;
    import mx.core.UIComponent;
    import mx.core.UITextField;

    public class AutoScrollManager extends EventDispatcher implements IMXMLObject {
        
        protected static const NEXT_FRAME_TIME : Number = 1;

        public function AutoScrollManager(target : IFlexDisplayObject = null) {
            super();

            _timer = new Timer(NEXT_FRAME_TIME, 1);
            _timer.addEventListener(TimerEvent.TIMER_COMPLETE, onTimerComplete);
        }
        
        public function initialized(document : Object, id : String) : void {
            _document = document ? IFlexDisplayObject(document) : IFlexDisplayObject(Application.application);
        }
        
        public function addInstance(container : Container) : void {
            if (!_containers.contains(container)) {
                container.addEventListener(FocusEvent.FOCUS_IN, onContainerFocusIn);
                _containers.addItem(container);
            }
        }
        
        public function removeInstance(container : Container) : void {
            if (_containers.contains(container)) {
                container.removeEventListener(FocusEvent.FOCUS_IN, onContainerFocusIn);
                _containers.removeItemAt(_containers.getItemIndex(container));
            }
        }
        
        protected function onContainerFocusIn(event : FocusEvent) : void {
            var target : InteractiveObject = InteractiveObject(event.target);
            _container = Container(event.currentTarget);

            if (_container.contains(target)) {
                _focused = (target is UITextField ? target.parent : target);
                _focusedChanged = true;
                if (!_timer.running) {
                    _timer.start();
                }
            }
        }
        
        protected function onTimerComplete(event : TimerEvent) : void {
            if (_focusedChanged) {
                var focusThickness : Number =
                    (_focused is UIComponent ?
                        UIComponent(_focused).getStyle("focusThickness") : 0);
    
                var viewMetricsAndPadding : EdgeMetrics = _container.viewMetricsAndPadding;
    
                var localPosition : Point = new Point(_focused.x, _focused.y);
                var globalPosition : Point = _focused.parent.localToGlobal(localPosition);
                var containerPosition : Point = _container.globalToLocal(globalPosition);

                var focusedBottom : Number = containerPosition.y + _focused.height + focusThickness;
                var containerBottom : Number = _container.height - viewMetricsAndPadding.bottom;
                if (focusedBottom > containerBottom) {
                    _container.verticalScrollPosition += (focusedBottom - containerBottom);
                }
                
                var focusedTop : Number = containerPosition.y - focusThickness;
                var containerTop : Number = viewMetricsAndPadding.top;
                if (focusedTop < containerTop) {
                    _container.verticalScrollPosition -= (containerTop - focusedTop);
                }
                
                var focusedRight : Number = containerPosition.x + _focused.width + focusThickness;
                var containerRight : Number = _container.width - viewMetricsAndPadding.right;
                if (focusedRight > containerRight) {
                    _container.horizontalScrollPosition += (focusedRight - containerRight);
                }
                
                var focusedLeft : Number = containerPosition.x - focusThickness;
                var containerLeft : Number = viewMetricsAndPadding.left;
                if (focusedLeft < containerLeft) {
                    _container.horizontalScrollPosition -= (containerLeft - focusedLeft);
                }
                
                _focusedChanged = false;
            }
        }
        
        private var _document : IFlexDisplayObject;
        
        private var _containers : ArrayCollection /* of containers */ = new ArrayCollection();
        
        private var _timer : Timer;
        
        private var _container : Container;
        
        private var _focused : InteractiveObject;
        
        private var _focusedChanged : Boolean;
        
    }

}

It could be instantiated either in MXML:

<autoscrollmanager id="autoScrollManager">

Or in ActionScript:

var autoScrollManager : AutoScrollManager = new AutoScrollManager();

MXML instantiation is usable in case you create custom containers (e. g. AdvancedBox extended from built-in Box) with autoScrollManager property defined:

public function get autoScrollManager() : AutoScrollManager {
    return _autoScrollManager;
}

public function set autoScrollManager(autoScrollManager : AutoScrollManager) : void {
    if (_autoScrollManager != null) {
        _autoScrollManager.removeInstance(this);
    }
    _autoScrollManager = autoScrollManager;
    _autoScrollManager.addInstance(this);
}

private var _autoScrollManager : AutoScrollManager;

So that you could use binding:

<AutoScrollManager id="autoScrollManager" />
<AdvancedBox id="advancedBox" autoScrollManager="{autoScrollManager}" />

Otherwise, use addInstance() method directly:

autoScrollManager.addInstance(advancedBox);

truncateToFit() performance problem

2006-12-12T16:58:00.000+02:00

Setting very long string to the text property of classes that decorate UITextField (e. g. Label) causes timeout exception. Take a look at the truncateToFit() method in UITextField class. You could find this block there:

while (s.length > 1 && textWidth + TEXT_WIDTH_PADDING > w) {
    s = s.slice(0, -1);
    super.text = s + truncationIndicator;
}

It means that actual text is cut char by char until result of its concatenation with truncation indicator fits into the width available or only one char left. When text is very long this looping is almost infinitive. I believe it would work much more faster with division by 2 approach. In this case even 64K text truncation will take only 16 loop cycles.

2006-12-12T10:52:00.001+02:00

My 1st post! :)